# space-monitor.pl
# Check the free space on some filesystem

sub get_space_status
{
&foreign_require("mount", "mount-lib.pl");
local $m;
foreach $f (&mount::list_mounted()) {
	$m = $f if ($f->[0] eq $_[0]->{'fs'});
	}
if ($m) {
	local @sp = &mount::disk_space($m->[2], $m->[0]);
	if ($sp[1] < $_[0]->{'min'}) {
		return { 'up' => 0 };
		}

	if ($_[0]->{'inode'} && defined(&mount::inode_space)) {
		# Do the inode check too
		local @isp = &mount::inode_space($m->[2], $m->[0]);
		if ($isp[1] < $_[0]->{'inode'}) {
			return { 'up' => 0,
				 'desc' => &text('space_ierr', $isp[1]) };
			}
		}

	return { 'up' => 1,
		 'desc' => &text('space_desc', &nice_size($sp[1]*1024)) };
	}
else {
	return { 'up' => -1,
		 'desc' => $text{'space_nofs'} };
	}
}

sub show_space_dialog
{
local $found;
&foreign_require("mount", "mount-lib.pl");
print "<tr> <td><b>$text{'space_fs'}</b></td>\n";
print "<td colspan=3><select name=fs>\n";
foreach $f (&foreign_call("mount", "list_mounted")) {
	if ($f->[2] !~ /swap|proc|auto/) {
		printf "<option %s>%s\n",
			$_[0]->{'fs'} eq $f->[0] ? 'selected' : '', $f->[0];
		$found++ if ($_[0]->{'fs'} eq $f->[0]);
		}
	}
printf "<option value='' %s>%s\n",
	$_[0]->{'fs'} && !$found ? 'selected' : '', $text{'space_other'};
print "</select>\n";
printf "<input name=other size=15 value='%s'></td>\n",
	$found ? '' : $_[0]->{'fs'};

print "<tr> <td><b>$text{'space_min2'}</b></td>\n";
print "<td>",&ui_bytesbox("min", $_[0]->{'min'}*1024),"</td>\n";

if (defined(&mount::inode_space)) {
	print "<td><b>$text{'space_inode'}</b></td>\n";
	print "<td>",&ui_textbox("inode", $_[0]->{'inode'}, 10),"</td>\n";
	}
print "</tr>\n";
}

sub parse_space_dialog
{
&depends_check($_[0], "mount");
$in{'min'} =~ /^[0-9\.]+$/ || &error($text{'space_emin'});
$_[0]->{'min'} = $in{'min'}*$in{'min_units'}/1024;
if ($in{'fs'}) {
	$_[0]->{'fs'} = $in{'fs'};
	}
else {
	$in{'other'} =~ /^\// || &error($text{'space_eother'});
	$_[0]->{'fs'} = $in{'other'};
	}
if (defined($in{'inode'})) {
	$_[0]->{'inode'} = $in{'inode'} ? int($in{'inode'}) : undef;
	}
}

